plugins {
    id "org.openapi.generator" version "6.2.0"
}

group = 'de.fettlaus'
version = '0.1.0'

apply plugin: 'base'
apply plugin: 'maven-publish'
apply plugin: 'java'

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

repositories {
    // Use Maven Central for resolving dependencies.
    mavenCentral()
}

sourceSets {
    main.java.srcDirs = ["$buildDir/generated/src/main/java"]
}

openApiGenerate {
    generatorName = "java"
    inputSpec = "$rootDir/aoclient_v1.yml".toString()
    outputDir = "$buildDir/generated".toString()
    apiPackage = "de.fettlaus.aoclient.api"
    invokerPackage = "de.fettlaus.aoclient.invoker"
    modelPackage = "de.fettlaus.aoclient.model"
    groupId = "de.fettlaus"
    id = "aoclient"
    version = "0.0.1"
    configOptions = [
        dateLibrary: "java8"
    ]
}

compileJava.dependsOn tasks.openApiGenerate

dependencies {
    implementation 'io.swagger:swagger-annotations:1.6.5'
    implementation "com.google.code.findbugs:jsr305:3.0.2"
    implementation 'com.squareup.okhttp3:okhttp:4.9.3'
    implementation 'com.squareup.okhttp3:logging-interceptor:4.9.3'
    implementation 'com.google.code.gson:gson:2.9.0'
    implementation 'io.gsonfire:gson-fire:1.8.5'
    implementation 'javax.ws.rs:jsr311-api:1.1.1'
    implementation 'javax.ws.rs:javax.ws.rs-api:2.1.1'
    implementation 'org.openapitools:jackson-databind-nullable:0.2.3'
    implementation group: 'org.apache.commons', name: 'commons-lang3', version: '3.12.0'
    implementation "jakarta.annotation:jakarta.annotation-api:1.3.5"
}

publishing {
    repositories {
        maven {
            url = 'https://git.fettlaus.de/api/packages/fettlaus/maven'
            name = 'gitea'
            authentication {
                header(HttpHeaderAuthentication)
            }
            credentials(HttpHeaderCredentials)
        }
    }

    publications {
        maven(MavenPublication) {
            artifactId = 'aoclient'
            from components.java
        }
    }
}